@echo off
setlocal enabledelayedexpansion
cls
set TITLE=Monitor Serial do Albert

echo -------------------------------
echo.
echo Albert Flash V0.0
echo.
echo %TITLE%
echo.
echo -------------------------------
echo.
timeout /t 3 /nobreak >nul

echo Detectando portas...
echo.

set FOUND=0

for /f %%a in ('powershell -Command "[System.IO.Ports.SerialPort]::GetPortNames()"') do (
    echo Testando %%a ...
    esptool.exe --port %%a chip_id >nul 2>&1
    if !errorlevel! == 0 (
        set PORT=%%a
        set FOUND=1
        goto :porta_ok
    )
)

:porta_ok
if !FOUND! == 0 (
    echo.
    echo ERRO: Nenhuma porta valida encontrada!
    echo Feche Arduino IDE ou outros programas usando a serial.
    pause
    exit
)

echo.
echo Porta valida encontrada: !PORT!
echo.

echo ==========================================
echo Monitor Serial iniciado
echo Para sair: CTRL + ]
echo ==========================================
echo.

python -m serial.tools.miniterm !PORT! 115200

if errorlevel 1 (
    echo.
    echo ERRO ao abrir monitor serial!
    echo Verifique Python/pyserial.
    pause
)